Gift: MMD VIP CODES + Requests (Mostly monthly updates)

RoseVelvette

@SymphoniaLoud does that world have a passcode to enter to see the dance stage to dance in the world?

average addict

@Odiro
how tf do we run shit locally no ones answered this

SymphoniaLoud

Its pretty easy:

Open your notepad or any other texteditor and save this code as a .bat file (for example: RunVRCWorlds.bat):

@echo off

set GameDir="C:\Program Files (x86)\Steam\steamapps\common\VRChat"
set GameExe="C:\Program Files (x86)\Steam\steamapps\common\VRChat\VRChat.exe"

if "%~1"=="" (
    echo Please drag and drop a VRCW file onto this batch file.
    pause
    exit /b
)

set "path=%~1"
set /a "randomid_a=10000+%random%"
set /a "randomid_b=10000+%random%"
set "randomid=%randomid_a%%randomid_b%"

start "" /D %GameDir% %GameExe% "--url=create?roomId=%randomid%&hidden=true&name=BuildAndRun&url=file:///%path%" --watch-worlds --watch-avatars

Put your all your .vrcw world files and the .bat in the same folder and drag the .vrcw on the .bat to run your your world in local test mode.
Have fun!

average addict

@SymphoniaLoud
dunno if im missing something, but I drag a vrcw onto it and it the command box just disappears and nothing happens.

SymphoniaLoud

@average-addict Make sure the path to your VRChat installation is correct.
You may need to enter it correctly.

If you want, you can send me a DM, and I'll help you via DC.

Tum

Is there a risk of getting banned if I open a world locally like that?

SymphoniaLoud

@RoseVelvette There is no passcode, the world is using a whitelist.

Anyways, the link for Room4Dancing Side .B hast been changed:
https://vrchat.com/home/world/wrld_34e1b084-8530-4fb3-90e3-e5718416b476/info

average addict

@SymphoniaLoud
path is correct, just doesn't seem to be doing anything.

SymphoniaLoud

@Tum said:

Is there a risk of getting banned if I open a world locally like that?

No, you just starting a local session that no one else can join.

it is like testing a world youre working on

average addict

@Tum
by the looks of the code it only opens the offline version of vrchat, so you shouldn't be at risk at all.

RoseVelvette

@SymphoniaLoud if the world using a whitelist how do we get on the list to dance in the world? Also is it part of patreon type of thing to be on the whitelist or No?

RoseVelvette

Is the VRMODELS.STORE page is it down cause it says gateway time out

Tum

I see. Thank you for letting me know.

jon117c

@average-addict Try this code. this is what i use. it also has a set of errors that will tell you whats wrong if it doesnt load.

What i do is i make a folder for each vrcw put this bat in there and launch the bat. it will find ur game and load. if you have more than 1 vrcw it will load the newest one.

@echo off
setlocal

set "GameDir=C:\Program Files (x86)\Steam\steamapps\common\VRChat"
set "GameExe=%GameDir%\VRChat.exe"

echo.

REM If a file was dragged onto the BAT, use it.
if not "%~1"=="" (
    set "WorldPath=%~f1"
) else (
    REM Otherwise find the newest VRCW in the same folder as this BAT.
    for /f "delims=" %%F in ('dir /b /a-d /o-d "%~dp0*.vrcw" 2^>nul') do (
        set "WorldPath=%~dp0%%F"
        goto :foundworld
    )

    echo ERROR: No VRCW file was found in:
    echo "%~dp0"
    goto :error
)

:foundworld

if not exist "%WorldPath%" (
    echo ERROR: VRCW file does not exist:
    echo "%WorldPath%"
    goto :error
)

if not exist "%GameExe%" (
    echo ERROR: VRChat.exe was not found:
    echo "%GameExe%"
    goto :error
)

set /a "randomid_a=10000+%random%"
set /a "randomid_b=10000+%random%"
set "randomid=%randomid_a%%randomid_b%"

echo Game:
echo "%GameExe%"
echo.
echo World:
echo "%WorldPath%"
echo.
echo Room ID:
echo %randomid%
echo.
echo Launching VRChat...
echo.

cd /d "%GameDir%"
if errorlevel 1 (
    echo ERROR: Could not change to the VRChat directory.
    goto :error
)

"%GameExe%" "--url=create?roomId=%randomid%&hidden=true&name=BuildAndRun&url=file:///%WorldPath%" --watch-worlds --watch-avatars

set "ExitCode=%errorlevel%"

echo.
echo VRChat exited.
echo Exit code: %ExitCode%
echo.
pause
exit /b %ExitCode%

:error
echo.
echo Launch failed.
echo.
pause
exit /b 1